# Maintainer: Alexandre Ferreira < alex.jorge.m [at] gmail.com >

_realname='wcwidth'
pkgbase="python-${_realname}"
pkgname="python-${_realname}"
pkgver=0.8.4
pkgrel=1
pkgdesc='Measures number of Terminal column cells of wide-character codes'
arch=('any')
url='https://github.com/jquast/wcwidth'
msys2_references=(
  'anitya: 88052'
  'archlinux: python-wcwidth'
  'cygwin: python-wcwidth'
  'gentoo: dev-python/wcwidth'
  'purl: pkg:pypi/wcwidth'
)
license=('spdx:MIT')
depends=(
  'python'
)
makedepends=(
  'python-build'
  'python-hatchling'
  'python-installer'
)
source=("${_realname}-${pkgver}.tar.gz::https://github.com/jquast/${_realname}/archive/${pkgver}.tar.gz")
noextract=("${_realname}-${pkgver}.tar.gz")
sha256sums=('2a775adb60b8e6de5e586bb0caa900b300d2bfe1ec959869d4de472365bea776')

prepare() {
  rm -rf "${_realname}-${pkgver}"

  # extract two times because symlinks can't be created without an existing file
  bsdtar -xzf "${srcdir}/${_realname}-${pkgver}.tar.gz" -C "${srcdir}" || true
  bsdtar -xzf "${srcdir}/${_realname}-${pkgver}.tar.gz" -C "${srcdir}" || true
}

build() {
  cd "${_realname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${_realname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
