# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>

_realname=lxml
pkgbase="python-${_realname}"
pkgname=("python-${_realname}")
pkgver=6.1.3
pkgrel=1
pkgdesc="Python binding for the libxml2 and libxslt libraries"
arch=('i686' 'x86_64')
url="https://lxml.de/"
msys2_repository_url="https://github.com/lxml/lxml"
msys2_references=(
  "archlinux: python-lxml"
  "cpe: cpe:/a:lxml:lxml"
  "gentoo: dev-python/lxml"
  "purl: pkg:pypi/lxml"
)
license=('spdx:BSD-3-Clause')
depends=(
  "libxml2"
  "libxslt"
  "python"
)
makedepends=(
  "cython"
  "gcc"
  "libxml2-devel"
  "libxslt-devel"
  "pkgconf"
  "python-build"
  "python-installer"
  "python-setuptools"
)
source=("https://github.com/lxml/lxml/archive/${_realname}-${pkgver}.tar.gz")
sha256sums=('33daa1ae6ec2410fb506befe36fd128ea53ade4dde145e1efdeebff69a76c1d5')

prepare() {
  mv "lxml-lxml-${pkgver}" "lxml-${pkgver}"
}

build() {
  cd "${_realname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${_realname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSES.txt "${pkgdir}/usr/share/licenses/python-${_realname}/LICENSES.txt"
}
