# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.su>

_realname='plotly'
pkgbase="mingw-w64-python-${_realname}"
pkgname="${MINGW_PACKAGE_PREFIX}-python-${_realname}"
pkgver=7.1.0
pkgrel=1
pkgdesc='An interactive, open-source, and browser-based graphing library for Python (mingw-w64)'
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url='https://plotly.com/python/'
msys2_repository_url='https://github.com/plotly/plotly.py'
msys2_references=(
  'anitya: 42303'
  'archlinux: python-plotly'
  'gentoo: dev-python/plotly'
  'purl: pkg:pypi/plotly'
)
license=('spdx:MIT')
depends=(
  "${MINGW_PACKAGE_PREFIX}-python"
  "${MINGW_PACKAGE_PREFIX}-python-narwhals"
  "${MINGW_PACKAGE_PREFIX}-python-packaging"
)
makedepends=(
  "${MINGW_PACKAGE_PREFIX}-python-build"
  "${MINGW_PACKAGE_PREFIX}-python-hatchling"
  "${MINGW_PACKAGE_PREFIX}-python-installer"
)
options=('!strip')
source=(
  "https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz"
)
sha256sums=('f860166a4a3d78c69cb1f4a15f28a5c8283eade98a282a698f3bb853a449ace5')

build() {
  cp -r "${_realname}-${pkgver}" "build-${MSYSTEM}" && cd "build-${MSYSTEM}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "build-${MSYSTEM}"

  MSYS2_ARG_CONV_EXCL="--prefix=" \
    python -m installer --prefix="${MINGW_PREFIX}" --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE.txt -t "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}"
}
